***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 18, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PEC3808C2A-AU 1 2
.param
+vc0 = 6.396e-11		 vc1 = 4.805e-11   	 vc2 = 1.300	   vc3 = 8.081e-14		 vc4 = 1.350
+tc1 = 1.331e-2		 tc2 = 1.501e-2		 tc3 = 3.855e-2      tc4 = 1.982e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 1 C zener
g1 C 1 value = {irexp(v(C,1))}
d2 2 C zener
g2 C 2 value = {irexp(v(C,2))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1e-15		   n = 1	        rs = 1e-3
+ibv = 1e-3		        nbv = 1.0	        bv = 9.8			
***** capacitance parameter *****
+cjo = 5.402e-11		   m = 1.951e-1		  vj = 5.654e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25	        eg = 1.0	        xti = 3
+trs1 = 1e-3		tbv1 = 3.509e-4		tbv2 = 8.015e-9
.ends PEC3808C2A-AU
*$
